Beitrags-Archiv für die Kategory 'Asterisk'

Oct 08

Originar llamadas en Asterisk

Monday, 8. October 2007 14:15

Somos muy cómodos. Para que vamos a engañarnos. Mi jefe dice que no es cuestión de comodidad, sino de productividad. Para qué vamos a tener que marcar un número de un cliente, si tenemos una preciosa base de datos con ellos. Así que me puse manos a la obra y fruto de investigar un poco, salió una pequeña "perla" para llamar desde nuestros teléfonos al cliente con solo hacer un click…

Para que el invento funcione necesitamos:

  1. Un servidor web
  2. Asterisk
  3. Perl

Para el artículo vamos a asumir que tenemos todo esto instalado en nuestra propia máquina (localhost). Empezamos por la configuración del asterisk. El script se conecta al manager de la centralita para lanzar los comandos (no la consola). Así que, lo primero que hay que hacer, es configurarlo. Nos vamos al fichero /etc/asterisk/manager.conf y lo dejamos así:

[general]
enabled = yes
port = 5038
bindaddr = 127.0.0.1

[originate]
read = call
write = call
permit = 127.0.0.1
secret = originatepass

Con esto hemos abierto la interfaz de administración de Asterisk y hemos creado un usuario originate con contraseña originatepass que tiene derechos para lanzar comandos del nivel call. Para más información sobre este tema, podéis pasaros por la sección Asterisk Manager Api de la excelente web voip-info.org

.La segunda parte del invento consiste básicamente en publicar el script que os pondré a continuación, a través de nuestro servidor web. Yo he usado apache así que os pongo cómo sería y dejo a cada cual buscarse el método que más le convenga:

ScriptAlias /asterisk /etc/asterisk/scripts

AllowOverride None
Options ExecCGI -MultiViews +SymLinksIfOwnerMatch
Order allow,deny
Allow from 127.0.0.1

Lo he limitado a la propia máquina aunque podéis modificar la directiva Allow para que solo se pueda acceder desde vuestra red local o quitarla directamente. Es importante que el servidor pueda acceder al directorio /etc/asterisk/scripts y que el script tenga permisos de ejecución, o veremos un bonito error 500.

Por último os dejo en este enlace el script originate.pl y además, os lo publico aquí para que le echéis un ojo directamente:

#!/usr/bin/perl -w
# Originate call from command line or cgi script
# Iñaki Rodriguez (2007)
# License: GPL

use IO::Socket::INET;
use strict;
use CGI;

my ($is_cgi,$cgi);
my ($channel,$local_ext,$data_ext,$destination_ext);
my $buffer;
my $debug = 1;

# Connection Data
my $host        = 'localhost';
my $timeout     = 5;
my $username    = 'originate';
my $secret      = 'originatepass';

if(!$ENV{'REMOTE_ADDR'}) {
        $is_cgi = 0;
        if ($ARGV[0] && $ARGV[1]) {
                $local_ext = int($ARGV[0]); # Origin Number
                $destination_ext = int($ARGV[1]); # Destination Number
        } else {
                print "Usage: ./originate.pl  \n";
                exit 1;
        }
} else {
        $is_cgi = 1;
        $cgi = new CGI;
        print $cgi->header();

        if($cgi->param('orig') && $cgi->param('dest')) {
                $local_ext = int($cgi->param('orig')); # Origin Number
                $destination_ext = int($cgi->param('dest')); # Destinatio Number
        } else {
                exit 1;
        }
}

if(!$local_ext || !$destination_ext) {
        print "Invalid values!!!\n";
        exit 1;
}

# Manager Connection
print "Connecting...\n" if $debug;

my $manager_sock = new IO::Socket::INET (PeerPort       => 5038,
                                         Proto          => 'tcp',
                                         PeerAddr       => $host,
                                         Timeout        => $timeout);

die ("Cannot connect to asterisk manager") if (!$manager_sock);
$manager_sock->recv($buffer,4096);

# Send Login Cmd
if(
$manager_sock->send("Action: Login\r\n".
                    "Username: $username\r\n"."Secret: $secret\r\n".
                    "ActionID: 1\r\n\r\n") == 0)
{
        print "Failed to send login information\n";
        exit(1);
}

$manager_sock->recv($buffer,4096);
print "Auth...\n" if $debug;

if($buffer =~ /^Response: Error/) {
        print "Failed to authenticate using $username and $secret\n";
        exit(1);
} 

# Send Originate Cmd
my $originate = "Action: Originate\r\n";
$originate .= "Channel: Local/$local_ext\\@default\r\n";
#$originate .= "Context: default\r\n";
$originate .= "Exten: $destination_ext\r\n";
$originate .= "Priority: 1\r\n\r\n";

# Enviamos y cerramos
$manager_sock->send($originate);

print "Calling...\n" if $debug;
$manager_sock->recv($buffer,4096);
print $buffer if $debug;
$manager_sock->close();

Antes de acabar, os comento un poco por encima el script. Debajo del comentario #Connection Data tenemos la sección de configuración. Solo tenemos que definir el host, el usuario y la contraseña. En nuestro caso, localhost, originate y originatepass respectívamente.

Cuando invoquemos el script con nuestra url http://localhost/asterisk/originate.pl?orig=600&dest=1004 conectará con el manager para abrir el canal y hacer la llamada. Otra cosa que no os he dicho, este script se puede lanzar desde la propia línea de comandos pasándole como argumentos la extensión y el número:
perl originate.pl 600 1004

Con esto acabamos por hoy. Aunque no será el último artículo sobre Asterisk ;)

Thema: Asterisk | Kommentare (0) | Autor: Iñaki